Understanding Society User Support

Thanks for your detailed explanation, Gundi

Hi Gundi,

I just wanted to make sure I am doing this OK.
These are the steps I've followed:

Get your pidp-COB lookup from the XWAVEDAT file (or the bw_indresp or w_indresp data files). Pointers to significant others such as the biological parent (*mnpid and *fnpid) are routinely provided in the indall data files. Create a long format data file that contains all pidp mnpid wave.

I’ve created a new data file which is the merged of the following files: xwavedat, indall and indresp. This file contains information of the responding and non-responding household members. I kept the variables pidp mnspid fnspid and a country of birth variable that I generated. Each row corresponds to one person, there are no duplicates. This file is saved as “pidpcob.dta”

Drop cases where mnpid equals -8 - no biological mother in household.
I created another data file where I only kept pidp mnspid and the country of birth variable. I dropped all individuals who are not living with their mother in the same household (drop if mnspid==-8). I saved this file as "pidp_mnspid.dta".

drop if h_mnspid==-8
rename pidp pidp_orig
rename indh_mnspid pidp
save "mnspid.dta", replace

Keep one observation per pidp (note that there will be some pidp who have more than one biological mother - obviously an error - that you need to correct). This is the pidp-biological mother lookup to which you can attach additional info about the mother. At this stage, there are only two variables: pidp mnpid. To attach the mother's COB, temporarily rename mnpid to pidp (requires renaming pidp to something else first).

I don't see any duplicates. (I run duplicates report pidp)
Using the file "pidp_mnspid.dta", I rename the pidp identifier to pidp_original and I rename mnspid to pidp. I saved this data.

Merge in the country of birth using pidp-COB lookup created in step 1. Keep only those with merge==3. When all required information about the mother has been added, undo the pidp and mnpid renames so pidp refers to the respondent and mnpid to their biological mother. Give the data relating to the mother a meaningful prefix. Save the data.

use "pidp_mnspid.dta", replace
merge m:1 pidp using "pidpcob.dta" // Matched: 19,009 (mothers).
rename pidp h_mnspid
rename pidp_orig pidp
rename cob_det cob_detmnspid
rename cob cobmnspid
keep if _merge==3

Am I proceeding correctly?
Thanks for your help

Hi Marina,

I am afraid something has gone wrong in your data merge as there really are respondents who have a different mother in different waves.

Here is how you can see it (following the procedure I suggested for spouses - step 5):

// Lookup file to mnspids
foreach x in a b c d e f g h {
use pidp `x'_mnspid using ${ukhls}/`x'_indall if `x'_mnspid!=-8, clear
gen wave=strpos("abcdefgh","`x'")
rename `x'_* *
save ${mydat}/pidp_mnspid_lookup_`x', replace
}
use ${mydat}/pidp_mnspid_lookup_a, clear
foreach x in b c d e f g h {
append using ${mydat}/pidp_mnspid_lookup_`x'
}

// Are there pidp who have different mnspids across time?
bys pidp (wave): gen index=_n
xtset pidp index
gen dif_mns_pidp=D.mnspid
fre dif_mns_pidp
bys pidp: egen mns_anydif=sum(dif_mns_pidp!=0 & dif_mns_pidp!=.)
lab var mns_anydif "Any change in mnspid over time?"
lab def mns_anydif 0"no", replace
lab val mns_anydif mns_anydif
fre mns_anydif

// Yes! And here is what the histories look like:
list pidp index wave mnspid dif mns_anydif if mns_anydif >0, sepby(pidp) noobs

// Save the PIDP-MNSPID-Lookup (long) to add the mothers' COB info to it.
drop index dif_mns_pidp
save ${mydat}/pidp_mnspid_lookup, replace

(add mothers' info). At some stage you want to re-shape this data to a wide format to merge with the youth file:

// Re-shape so there is just one row per PIDP
xtset pidp wave
reshape wide mnspid, i(pidp) j(wave)
describe
// PIDP- with mnspid for each wave (and any other info about mothers such as .... mns_cob1 etc.)
save ${mydat}/pidp_mnspid_lookup_wide, replace

Hope this helps,
Gundi

Thanks, Gundi. I think the confusion is because you thought I was using all waves, but I am only using the last wave.
Marina

Hi Marina,
I see - sorry for that. If it is just one wave your code seems to be fine. The h_indall file has 19,009 cases with mnspid~=-8.

Best wishes,
Gundi

Dear Gundi,

Thanks for your help. I have now a file with all the children below age 16 (1 child per row) and I have also the variables indicating the country of birth of their natural/step/adoptive mother and father. I have created a variable that combines both information about parents' country of birth. I have also rely on information about the parents' interview outcome and parents' de facto marital status to understand why sometimes the information about the mother/father country of birth is missing. The main problem I have now is that I get inconsistent results when I crosstab the variable that I've generated (about parents' country of birth) with h_fborn, which is a household-level variable indicating if there is somebody in the household that was born abroad. I find that, for example, some households reported that nobody is born abroad but then I know that the parents of 148 children living in those households were both born in a non-EU country. Are these discrepancies normal? Should I use h_fborn at all?

Thanks

Marina